@echo off

REM Dette program skal køres fra "RAD Studio Command Prompt"


REM Versionsnr skal sættes både som variabel her men også i projekt filen
SET VER=6_2_4

REM ryd eksisterende indhold af %STED%
SET STED=

REM cleaning files
DEL *.dcu /S
DEL *.exe /S


SET BUILDDIR=Install\RuteLabels

RMDIR %BUILDDIR% /S /Q
MKDIR %BUILDDIR%


REM START BUILD AF VARIANTERNE
REM 

SET DIST=BK
CALL :SUB_BUILD


REM TK er BK's lokation hos TrykKompagniet i Hvidovre
SET DIST=TK
CALL :SUB_BUILD


SET DIST=DBK
CALL :SUB_BUILD


SET DIST=FD
CALL :SUB_BUILD

SET DIST=NS
CALL :SUB_BUILD



REM BYG DAO varianter

SET DIST=DAO

SET STED=_BRA
CALL :SUB_BUILD

SET STED=_GLL
CALL :SUB_BUILD

SET STED=_ALB
CALL :SUB_BUILD


GOTO EOF


:SUB_BUILD
REM Denne subroutine sørger for at builde varianten der passer på %DIST% og opretter installationsmapper med alt
REM tilhørende indhold
ECHO ---------------------------------------------------------------------------
ECHO Builder %DIST% %STED%
DEL *.dcu /S

SET DIR=%BUILDDIR%\RuteLabels_ver%VER%_%DIST%%STED%_omdelinginfo

msbuild.exe RuteLabels.dproj /p:Config=Release;DCC_Define=STED_%DIST%
MKDIR %DIR%
MKDIR %DIR%\Docs
MKDIR %DIR%\Logs
MKDIR %DIR%\Sounds
COPY Help\Manual*.pdf %DIR%\Docs
COPY Sounds\* %DIR%\Sounds
COPY IniTemplates\%DIST%%STED%.ini %DIR%\RuteLabels.ini
COPY RuteLabels.exe %DIR%
EXIT /B
REM End of Build sub routine


:EOF

ECHO ----------------------------------------------------------------------
ECHO Rydder op
DEL RuteLabels.exe
DEL *.dcu /S